Name: Cámara OV5640 100°/160°/200°/3.6mm
SKU: 281085
Availability: InStock

INFORMACIÓN

La cámara OV5640 es un dispositivo para capturar imágenes digitales de baja potencia y alta resolución. Esta disponible con lente 100° Sin distorsión, 160° con lente angular, 200° con lente angular y con lente de 3.6 mm, la elección de cámara dependerá de la aplicación de tu proyecto.

La cámara OV5640 se integra en robots y vehículos autónomos para proporcionar capacidad de visión, en proyectos de Internet de las Cosas (IoT) para capturar imágenes y transmitirlas a través de redes inalámbricas, se puede utilizar en sistemas de vigilancia y seguridad para capturar imágenes y videos.

ESPECIFICACIONES Y CARACTERÍSTICAS

Modelo del Chip: OV5640
Interfaz: MIPI/DUP
Lente: 2G+4P
Pixeles: 5 millones de píxeles
Longitud focal: 1.15mm
Tamaño CCD: 1/4 Pulgada
Resolución: 1600 x 1200
Campo de visión y lentes
- 100° sin distorsión
- 160° con lente angular
- 200° con lente angular
- Lente de 3.6 mm

DOCUMENTACIÓN Y RECURSOS

Datasheet OV5640
Dimensiones

INFORMACIÓN ADICIONAL

Estas cámaras tiene compatibilidad con Esp32-CAM en su descripción puedes obtener mas detalle de configuración y manejo del Esp32.

El siguiente código se utiliza para reconocer y visualizar las cámaras OV5640, por medio de una conexión Wifi.

Al conectarse a tu red Wifi , te mostrara la IP asignada por el puerto serial para poder configurar los parámetros de la cámara.

Código

#include "esp_camera.h"
#include <WiFi.h>
#define CAMERA_MODEL_AI_THINKER // Tiene PSRAM
#include "camera_pins.h"

// ===========================
// Ingresa el nombre y contraseña de tu Red WiFi
// ===========================
const char* ssid = "Nombre de tu Red";
const char* password = "Contraseña de tu Red";

void startCameraServer();
void setupLedFlash(int pin);

void setup() {
  Serial.begin(115200);
  Serial.setDebugOutput(true);
  Serial.println();

  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sccb_sda = SIOD_GPIO_NUM;
  config.pin_sccb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.frame_size = FRAMESIZE_UXGA;
  config.pixel_format = PIXFORMAT_JPEG; // Para transmisión
  //config.pixel_format = PIXFORMAT_RGB565; // Para reconocimiento/detección de rostros
  config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;
  config.fb_location = CAMERA_FB_IN_PSRAM;
  config.jpeg_quality = 12;
  config.fb_count = 1;
  
  // Se el CI SPRAM esta presente inicia con resolución UXGA y mayor calidad JPEG
  //                      para un buffer de trama preasignado más grande.
  if(config.pixel_format == PIXFORMAT_JPEG){
    if(psramFound()){
      config.jpeg_quality = 10;
      config.fb_count = 2;
      config.grab_mode = CAMERA_GRAB_LATEST;
    } else {
      // Limita el tamaño del frame cuando PSRAM no esta disponible
      config.frame_size = FRAMESIZE_SVGA;
      config.fb_location = CAMERA_FB_IN_DRAM;
    }
  } else {
    // Mejor opción para detección/reconocimiento facial.
    config.frame_size = FRAMESIZE_240X240;
#if CONFIG_IDF_TARGET_ESP32S3
    config.fb_count = 2;
#endif
  }

#if defined(CAMERA_MODEL_ESP_EYE)
  pinMode(13, INPUT_PULLUP);
  pinMode(14, INPUT_PULLUP);
#endif

  // Inicialización de la camara
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("Fallo la inicialización de la Camara con error 0x%x", err);
    return;
  }

  sensor_t * s = esp_camera_sensor_get();
  // los sensores iniciales están volteados verticalmente y los colores están un poco saturados.
  if (s->id.PID == OV3660_PID) {
    s->set_vflip(s, 1); // flip it back
    s->set_brightness(s, 1); // eleva el brillo solo un poco
    s->set_saturation(s, -2); // reduce la saturación
  }
  // Reduce el tamaño del fotograma para obtener una mayor velocidad inicial de fotogramas.
  if(config.pixel_format == PIXFORMAT_JPEG){
    s->set_framesize(s, FRAMESIZE_QVGA);
  }

#if defined(CAMERA_MODEL_M5STACK_WIDE) || defined(CAMERA_MODEL_M5STACK_ESP32CAM)
  s->set_vflip(s, 1);
  s->set_hmirror(s, 1);
#endif

#if defined(CAMERA_MODEL_ESP32S3_EYE)
  s->set_vflip(s, 1);
#endif

// Configura el flash LED si está definido en camera_pins.h
#if defined(LED_GPIO_NUM)
  setupLedFlash(LED_GPIO_NUM);
#endif

  WiFi.begin(ssid, password);
  WiFi.setSleep(false);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi Conectado");

  startCameraServer();

  Serial.print("Camara Lista! Usa 'http://");
  Serial.print(WiFi.localIP());
  Serial.println("' para conectarte");
}

void loop() {
  //No hagas nada. Todo se hace en otra tarea por parte del servidor Web.
  delay(10000);
}